Écart type sur Excel : ECARTYPE.STANDARD ou ECARTYPE.PEARSON ?

L'écart type mesure de combien les valeurs d'une série s'éloignent, en moyenne, de leur moyenne. Dans Excel, on le calcule avec =ECARTYPE.STANDARD(B2:B7) quand les données sont un échantillon (le cas le plus courant), ou avec =ECARTYPE.PEARSON(B2:B7) quand elles couvrent toute la population étudiée.
Le résultat s'exprime dans la même unité que les données : en euros pour un chiffre d'affaires, en jours pour un délai. Plus il est grand, plus les valeurs sont dispersées.
Exemple : deux boutiques, même moyenne, dispersion différente
Voici le chiffre d'affaires hebdomadaire de deux boutiques sur six semaines :
| A | B | C | |
|---|---|---|---|
| 1 | Semaine | Lyon (€) | Nantes (€) |
| 2 | S1 | 1 200 | 900 |
| 3 | S2 | 1 250 | 1 500 |
| 4 | S3 | 1 180 | 1 100 |
| 5 | S4 | 1 220 | 1 400 |
| 6 | S5 | 1 150 | 1 000 |
| 7 | S6 | 1 200 | 1 300 |
Les deux boutiques ont la même moyenne : =MOYENNE(B2:B7) et =MOYENNE(C2:C7) renvoient toutes les deux 1 200 €. L'écart type montre ce que la moyenne cache :
=ECARTYPE.STANDARD(B2:B7)renvoie 34,06 € pour Lyon ;=ECARTYPE.STANDARD(C2:C7)renvoie 236,64 € pour Nantes.
Lyon vend à peu près la même chose chaque semaine. Nantes alterne bonnes et mauvaises semaines : prévoir le stock ou le planning y est plus difficile. Pour le montrer, tracez un graphique en courbes avec les deux colonnes : la courbe de Lyon reste presque plate, celle de Nantes monte et descend d'une semaine à l'autre.
ECARTYPE.STANDARD ou ECARTYPE.PEARSON : laquelle choisir ?
Les deux fonctions font le même calcul, à un détail près : la somme des écarts au carré est divisée par n − 1 pour ECARTYPE.STANDARD et par n pour ECARTYPE.PEARSON (n = nombre de valeurs).
- ECARTYPE.STANDARD (échantillon) : vos données sont une partie d'un ensemble plus grand et vous voulez en tirer une conclusion générale. Six semaines de ventes pour juger de la régularité d'une boutique, 50 clients interrogés sur 2 000, 20 pièces contrôlées sur une production : c'est un échantillon.
- ECARTYPE.PEARSON (population) : vos données contiennent tous les éléments qui vous intéressent, et vous ne cherchez pas à généraliser. Les notes des 28 élèves d'une classe pour décrire cette classe, les salaires de tous les employés d'une petite entreprise : c'est la population entière.
En cas de doute, prenez ECARTYPE.STANDARD. Sur notre exemple :
| Boutique | ECARTYPE.STANDARD | ECARTYPE.PEARSON |
|---|---|---|
| Lyon | 34,06 € | 31,09 € |
| Nantes | 236,64 € | 216,02 € |
ECARTYPE.STANDARD donne toujours un résultat un peu plus grand. L'écart se voit sur 6 valeurs ; sur plusieurs centaines, les deux résultats deviennent presque identiques.
Les autres fonctions d'écart type d'Excel
Dans la liste des fonctions, vous croiserez six noms. Voici à quoi ils correspondent :
| Fonction | Type de données | À savoir |
|---|---|---|
| ECARTYPE.STANDARD | Échantillon | La fonction à utiliser par défaut. |
| ECARTYPE.PEARSON | Population | Quand vous avez toutes les valeurs. |
| ECARTYPE | Échantillon | Ancien nom, même résultat qu'ECARTYPE.STANDARD. Conservée pour la compatibilité avec les vieux classeurs. |
| ECARTYPEP | Population | Ancien nom, même résultat qu'ECARTYPE.PEARSON. |
| STDEVA | Échantillon | Compte aussi le texte (comme 0) et les valeurs logiques (VRAI = 1, FAUX = 0) présents dans la plage. |
| STDEVPA | Population | Même logique que STDEVA, pour une population. |
ECARTYPE.STANDARD et ECARTYPE.PEARSON ignorent les cellules vides, le texte et les valeurs logiques d'une plage. STDEVA et STDEVPA servent rarement : on les utilise quand une cellule « absent » ou FAUX doit compter comme un zéro.
Lire le résultat
Un écart type seul ne dit pas grand-chose : 236 €, c'est beaucoup pour un chiffre d'affaires de 1 200 €, très peu pour un chiffre d'affaires de 100 000 €. Pour comparer, rapportez-le à la moyenne. C'est le coefficient de variation :
=ECARTYPE.STANDARD(B2:B7)/MOYENNE(B2:B7)
Au format pourcentage, la formule donne 2,8 % pour Lyon et 19,7 % pour Nantes. Ce ratio permet aussi de comparer des séries qui n'ont ni la même unité ni le même ordre de grandeur.
Un écart type de 0 signifie que toutes les valeurs sont identiques. Il n'est jamais négatif.
Écart type avec une condition
Si vos données sont rangées en liste (une colonne Ville en A, une colonne Montant en B, lignes 2 à 13), Excel n'a pas de fonction « ECARTYPE.SI ». Imbriquez un SI dans ECARTYPE.STANDARD :
=ECARTYPE.STANDARD(SI(A2:A13="Lyon";B2:B13))
SI renvoie le montant pour les lignes « Lyon » et FAUX pour les autres, que la fonction ignore. Dans Excel 365 et 2021, la formule se valide avec Entrée. Dans les versions plus anciennes, validez-la avec Ctrl + Maj + Entrée (formule matricielle), sinon elle ne renvoie pas le bon résultat.
Avec Excel 365 ou 2021, FILTRE donne une formule plus lisible :
=ECARTYPE.STANDARD(FILTRE(B2:B13;A2:A13="Lyon"))
Erreurs et résultats inattendus
#DIV/0!
ECARTYPE.STANDARD a besoin d'au moins deux nombres (elle divise par n − 1). Une plage qui ne contient qu'un nombre, ou que du texte, renvoie #DIV/0!. Vérifiez combien de nombres Excel voit réellement avec =NB(B2:B7).
Résultat trop faible ou trop élevé
- Nombres stockés en texte : des montants importés (alignés à gauche, petit triangle vert) sont ignorés sans message d'erreur. Si
=NB(B2:B7)renvoie moins que le nombre de lignes, convertissez-les (bouton d'avertissement, puis « Convertir en nombre »). - Zéro au lieu d'une cellule vide : une semaine sans donnée saisie 0 compte comme une semaine à 0 €, ce qui gonfle fortement l'écart type. Laissez la cellule vide si la valeur est inconnue.
- Ligne de total dans la plage : si la plage inclut la ligne Total, cette valeur très éloignée des autres fausse tout le calcul.
Pour une moyenne où chaque valeur n'a pas le même poids, voyez notre tutoriel sur la moyenne pondérée dans Excel. La documentation Microsoft détaille la fonction ECARTYPE.STANDARD.


